***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*May 24, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt BAS40AW-AU 1 2 3 
.param
+vc0 = 0 		vc1 = 9.203e-12		vc2 = 3.252e-9		vc3 = 7.517e-2
+tc1 = 1.432e-3		tc2 = 7.119e-2		tc3 = 5.432e-2		tc4 = 3.885e-2	
d1 3 1 diode
g1 1 3 value = {(vc0+vc1*v(1,3))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+vc2*exp(vc3*v(1,3))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d2 3 2 diode
g2 2 3 value = {(vc0+vc1*v(2,3))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+vc2*exp(vc3*v(2,3))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
.model diode d
***** flag parameter *****
+level = 1
***** dc model parameter *****
+ is = 7.196e-9		   n = 1.071		  rs = 2.787		ikf = 1.173e-2
+ibv = 0.1e-3		 nbv = 1		  bv = 44
***** capacitance parameter *****
+cjo = 3.614e-12	   m = 0.357		  vj = 0.391
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 0.619		 xti = 3
+trs1 = -2.312e-3	trs2 = -2.251e-5
+tikf = -6.511e-3
.ends BAS40AW-AU
*$
